Family Forum 261/SOMC Family Forum 261.iso/Xtras/Behavior Library.cst/00048_Script_UI Rollover Change Member

Text File | 1997-11-17 | 2KB | 53 lines

-- Rollover Change Member


-- behavior library version 1.1
-- a control

-- Display an alternate Image when mouse Pointer is over the sprite.

property  standardImage, alternateImage, nextCM

on mouseEnter me
  set the member of sprite the spritenum of me = the alternateImage of me
end

on mouseLeave me
  set the member of sprite the spritenum of me = the standardImage of me
end

---

on beginSprite me
  set the standardImage of me = the member of sprite the spriteNum of me

  if nextCM = 1 then
    set memref = the member of sprite the currentspritenum
    set castlibnum = the castlibnum of memref
    set memdefault = member (the membernum of member memref + 1) of castlib castlibnum
    set alternateImage = memdefault
  end if

end

on getPropertyDescriptionList


  if the currentspritenum = 0 then
    set memdefault = 0
  else
    set memref = the member of sprite the currentspritenum
    set castlibnum = the castlibnum of memref
    set memdefault = member (the membernum of member memref + 1) of castlib castlibnum
  end if


  set p_list = [      #nextCM: [ #comment:   "Use Next Member:",                     #format:   #boolean,                    #default:    1 ],   #alternateImage: [ #comment:   "Rollover Cast Member:",                     #format:   #graphic,                    #default:    memdefault ]                  ]
  return p_list
end

on getBehaviorDescription
  return "Change the sprite's cast member when the mouse rolls over the current sprite." & RETURN & "PARAMETERS:" & RETURN & "ò Use Next Member - Turn this option on to automatically display the next cast member in the cast when mouse rolls over the sprite."& RETURN & "ò Rollover Cast Member - Choose a specific cast member to appear when the mouse rolls over the sprite. This setting is ignored if Use Next Member is on."
end